@echo off
rem pls2wpl.bat written by Michael John Wensley http://www.wensley.org.uk/
rem based on catalog.bat found in dos batch examples at http://www.robvanderwoude.com
rem This batch file converts XMMS .PLS files into .wpl playlists for use
rem with windows media player
rem suggested batch location = My Documents\My Music\My Playlists
echo ^<?wpl version="1.0"?^>>%TEMP%\convert.wpl
echo ^<smil^>>>%TEMP%\convert.wpl
echo ^<head^>>>%TEMP%\convert.wpl
echo ^<meta name="Generator" content="PLS to WPL playlist conversion"/^>>>%TEMP%\convert.wpl
echo ^<title^>Playlist^</title^>>>%TEMP%\convert.wpl
echo ^<body^>>>%TEMP%\convert.wpl
echo ^<seq^>>>%TEMP%\convert.wpl
for /f "tokens=1,2* delims==" %%A in ('type %*') do (
	for /f "tokens=1 delims=i" %%U in ("%%A") do (
		if [%%U]==[F] (
			echo ^<media src="%%B"/^>>>%TEMP%\convert.wpl
		)
	)
)
echo ^</seq^>>>%TEMP%\convert.wpl
echo ^</body^>>>%TEMP%\convert.wpl
echo ^</head^>>>%TEMP%\convert.wpl
echo ^</smil^>>>%TEMP%\convert.wpl
start %TEMP%\convert.wpl